# Built by `make pkg` at the repo root, from `git archive HEAD`.
pkgname=neferwl
pkgver=0.0.0
pkgrel=1
pkgdesc='Minimal Wayland compositor with column tiling, for the TTY'
arch=('x86_64')
url='https://github.com/bnema/neferwl'
license=('GPL-3.0-only')
# Loaded at runtime (purego, no cgo): not seen by makepkg's library scan.
depends=('glibc' 'libinput' 'libxkbcommon' 'seatd' 'systemd-libs' 'vulkan-icd-loader'
	'vulkan-driver' 'wayland' 'dbus' 'libcap')
makedepends=('go')
optdepends=('xwayland-satellite>=0.7: X11 apps'
	'foot: default terminal'
	'fuzzel: launcher'
	'xdg-desktop-portal-gtk: file pickers and settings for apps'
	'xdg-desktop-portal-wlr: screen sharing and screenshots through the portal'
	'nefercap: screenshots and screen recording')
install=neferwl.install
source=("$pkgname-$pkgver.tar.gz")
sha256sums=('SKIP')

prepare() {
	cd "$pkgname-$pkgver"
	export GOPATH="$srcdir/gopath" GOFLAGS='-mod=readonly -modcacherw' GOWORK=off GOTOOLCHAIN=local
	go mod download
	go mod vendor
}

build() {
	cd "$pkgname-$pkgver"
	export CGO_ENABLED=0 GOFLAGS='-mod=vendor -trimpath -buildvcs=false -buildmode=pie' GOPROXY=off GOWORK=off GOTOOLCHAIN=local
	go build -ldflags "-X main.version=$pkgver" -o neferwl ./cmd/neferwl
}

check() {
	cd "$pkgname-$pkgver"
	./neferwl version
	./neferwl validate-config examples/config
}

package() {
	cd "$pkgname-$pkgver"
	install -Dm755 neferwl "$pkgdir/usr/bin/neferwl"
	install -Dm755 packaging/neferwl-session "$pkgdir/usr/bin/neferwl-session"
	install -Dm644 packaging/neferwl.service "$pkgdir/usr/lib/systemd/user/neferwl.service"
	install -Dm644 packaging/neferwl-shutdown.target "$pkgdir/usr/lib/systemd/user/neferwl-shutdown.target"
	install -Dm644 packaging/neferwl.desktop "$pkgdir/usr/share/wayland-sessions/neferwl.desktop"
	install -Dm644 packaging/neferwl-portals.conf "$pkgdir/usr/share/xdg-desktop-portal/neferwl-portals.conf"
	install -Dm644 examples/config "$pkgdir/usr/share/doc/neferwl/config.example"
	install -Dm644 examples/capture-allow "$pkgdir/usr/share/doc/neferwl/capture-allow.example"
	install -Dm644 README.md "$pkgdir/usr/share/doc/neferwl/README.md"
	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/neferwl/LICENSE"
}