PKGBUILD RawHistoryFolder

1# Maintainer: bnema <b at bnema dot dev>
2# The release workflow sets pkgver and publishes this file to the AUR on every
3# release tag, so the AUR version never falls behind the latest tag.
4pkgname=neferafk-git
5pkgver=0.0.0.r0.g0000000
6pkgrel=1
7pkgdesc='Idle daemon for Wayland: fade, session lock, screens off and suspend (git version)'
8arch=('x86_64' 'aarch64')
9url='https://github.com/bnema/neferafk'
10license=('GPL-3.0-only')
11# Loaded at runtime (purego, no cgo): not seen by makepkg's library scan.
12depends=('glibc' 'pam' 'libxkbcommon' 'vulkan-icd-loader' 'vulkan-driver' 'systemd'
13	'ttf-dejavu') # lock screen monospace font (DejaVu Sans Mono)
14makedepends=('go>=2:1.27' 'git')
15optdepends=('pass: PIN source for auth.mode = pin')
16provides=('neferafk')
17conflicts=('neferafk' 'neferafk-bin')
18backup=('etc/pam.d/neferafk')
19source=('git+https://github.com/bnema/neferafk.git')
20sha256sums=('SKIP')
21
22pkgver() {
23	cd neferafk
24	# v0.2.0-5-gabc1234 -> 0.2.0.r5.gabc1234. Pre-release tags (v0.3.0-rc1)
25	# are skipped: pacman sorts 0.3.0.rc1 after 0.3.0.
26	git describe --long --tags --abbrev=7 --exclude='*-*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
27}
28
29prepare() {
30	cd neferafk
31	export GOPATH="$srcdir/gopath" GOFLAGS='-mod=readonly -modcacherw' GOTOOLCHAIN=local
32	go mod download
33}
34
35build() {
36	cd neferafk
37	export GOPATH="$srcdir/gopath" CGO_ENABLED=0 GOTOOLCHAIN=local GOPROXY=off
38	export GOFLAGS='-mod=readonly -modcacherw -trimpath -buildvcs=false -buildmode=pie'
39	go build -ldflags "-X main.version=$pkgver" -o neferafk ./cmd/neferafk
40}
41
42check() {
43	cd neferafk
44	./neferafk version
45	./neferafk validate-config examples/config
46}
47
48package() {
49	cd neferafk
50	install -Dm755 neferafk "$pkgdir/usr/bin/neferafk"
51	install -Dm644 packaging/neferafk.pam "$pkgdir/etc/pam.d/neferafk"
52	install -Dm644 examples/config "$pkgdir/usr/share/doc/neferafk/config.example"
53	install -Dm644 README.md "$pkgdir/usr/share/doc/neferafk/README.md"
54	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
55}