PKGBUILD RawHistoryFolder

1# Built by `make pkg` at the repo root, from `git archive HEAD`.
2pkgname=neferafk
3pkgver=0.0.0
4pkgrel=1
5pkgdesc='Idle daemon for Wayland: fade, session lock, screens off and suspend'
6arch=('x86_64')
7url='https://github.com/bnema/neferafk'
8license=('GPL-3.0-only')
9# Loaded at runtime (purego, no cgo): not seen by makepkg's library scan.
10depends=('glibc' 'pam' 'libxkbcommon' 'vulkan-icd-loader' 'vulkan-driver' 'systemd'
11	'ttf-dejavu') # lock screen monospace font (DejaVu Sans Mono)
12makedepends=('go>=2:1.27')
13optdepends=('pass: PIN source for auth.mode = pin')
14backup=('etc/pam.d/neferafk')
15source=("$pkgname-$pkgver.tar.gz")
16sha256sums=('SKIP')
17
18prepare() {
19	cd "$pkgname-$pkgver"
20	export GOPATH="$srcdir/gopath" GOFLAGS='-mod=readonly -modcacherw' GOWORK=off GOTOOLCHAIN=local
21	go mod download
22	go mod vendor
23}
24
25build() {
26	cd "$pkgname-$pkgver"
27	export CGO_ENABLED=0 GOFLAGS='-mod=vendor -trimpath -buildvcs=false -buildmode=pie' GOPROXY=off GOWORK=off GOTOOLCHAIN=local
28	go build -ldflags "-X main.version=$pkgver" -o neferafk ./cmd/neferafk
29}
30
31check() {
32	cd "$pkgname-$pkgver"
33	./neferafk version
34	./neferafk validate-config examples/config
35}
36
37package() {
38	cd "$pkgname-$pkgver"
39	install -Dm755 neferafk "$pkgdir/usr/bin/neferafk"
40	install -Dm644 packaging/neferafk.pam "$pkgdir/etc/pam.d/neferafk"
41	install -Dm644 examples/config "$pkgdir/usr/share/doc/neferafk/config.example"
42	install -Dm644 README.md "$pkgdir/usr/share/doc/neferafk/README.md"
43	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/neferafk/LICENSE"
44}