PKGBUILD RawHistoryFolder

1# Maintainer: bnema <b at bnema dot dev>
2# The release workflow sets pkgver and publishes this file to the AUR on every
3# release tag, so the AUR version never falls behind the latest tag.
4pkgname=neferbar-git
5pkgver=0.0.0.r0.g0000000
6pkgrel=1
7pkgdesc='One-cell-high, terminal-style status bar for Wayland, driven by scripts (git version)'
8arch=('x86_64' 'aarch64')
9url='https://github.com/bnema/neferbar'
10license=('MIT')
11# Loaded at runtime (purego, no cgo): not seen by makepkg's library scan.
12# fontconfig provides fc-match, which finds the font files.
13depends=('glibc' 'fontconfig' 'libxkbcommon' 'vulkan-icd-loader' 'vulkan-driver')
14makedepends=('go>=2:1.27' 'git')
15optdepends=('ttf-jetbrains-mono-nerd: default font, with the icons modules print')
16provides=('neferbar')
17conflicts=('neferbar' 'neferbar-bin')
18source=('git+https://github.com/bnema/neferbar.git')
19sha256sums=('SKIP')
20
21pkgver() {
22	cd neferbar
23	# v0.2.0-5-gabc1234 -> 0.2.0.r5.gabc1234. Pre-release tags (v0.3.0-rc1)
24	# are skipped: pacman sorts 0.3.0.rc1 after 0.3.0.
25	git describe --long --tags --abbrev=7 --exclude='*-*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
26}
27
28prepare() {
29	cd neferbar
30	export GOPATH="$srcdir/gopath" GOFLAGS='-mod=readonly -modcacherw' GOTOOLCHAIN=local
31	go mod download
32}
33
34build() {
35	cd neferbar
36	export GOPATH="$srcdir/gopath" CGO_ENABLED=0 GOTOOLCHAIN=local GOPROXY=off
37	export GOFLAGS='-mod=readonly -modcacherw -trimpath -buildvcs=false -buildmode=pie'
38	go build -ldflags "-X main.version=$pkgver" -o neferbar ./cmd/neferbar
39}
40
41check() {
42	cd neferbar
43	./neferbar version
44}
45
46package() {
47	cd neferbar
48	install -Dm755 neferbar "$pkgdir/usr/bin/neferbar"
49	install -Dm644 README.md "$pkgdir/usr/share/doc/neferbar/README.md"
50	cp -r examples "$pkgdir/usr/share/doc/neferbar/examples"
51	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
52}