PKGBUILD RawHistoryFolder

1# Built by `make pkg` at the repo root, from `git archive HEAD`.
2pkgname=neferbar
3pkgver=0.0.0
4pkgrel=1
5pkgdesc='One-cell-high, terminal-style status bar for Wayland, driven by scripts'
6arch=('x86_64' 'aarch64')
7url='https://github.com/bnema/neferbar'
8license=('MIT')
9# Loaded at runtime (purego, no cgo): not seen by makepkg's library scan.
10# fontconfig provides fc-match, which finds the font files.
11depends=('glibc' 'fontconfig' 'libxkbcommon' 'vulkan-icd-loader' 'vulkan-driver')
12makedepends=('go>=2:1.27')
13optdepends=('ttf-jetbrains-mono-nerd: default font, with the icons modules print')
14source=("$pkgname-$pkgver.tar.gz")
15sha256sums=('SKIP')
16
17prepare() {
18	cd "$pkgname-$pkgver"
19	export GOPATH="$srcdir/gopath" GOFLAGS='-mod=readonly -modcacherw' GOWORK=off GOTOOLCHAIN=local
20	go mod download
21	go mod vendor
22}
23
24build() {
25	cd "$pkgname-$pkgver"
26	export CGO_ENABLED=0 GOFLAGS='-mod=vendor -trimpath -buildvcs=false -buildmode=pie' GOPROXY=off GOWORK=off GOTOOLCHAIN=local
27	go build -ldflags "-X main.version=$pkgver" -o neferbar ./cmd/neferbar
28}
29
30check() {
31	cd "$pkgname-$pkgver"
32	./neferbar version
33}
34
35package() {
36	cd "$pkgname-$pkgver"
37	install -Dm755 neferbar "$pkgdir/usr/bin/neferbar"
38	install -Dm644 README.md "$pkgdir/usr/share/doc/neferbar/README.md"
39	cp -r examples "$pkgdir/usr/share/doc/neferbar/examples"
40	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/neferbar/LICENSE"
41}