PKGBUILD RawHistoryFolder

1# Maintainer: bnema <b at bnema dot dev>
2# The release workflow sets pkgver and publishes this file to the AUR on every
3# release tag, so the AUR version never falls behind the latest tag.
4pkgname=nefercap-git
5pkgver=0.0.0.r0.g0000000
6pkgrel=1
7pkgdesc='Screenshots and silent screen recording for Wayland, from one shortcut (git version)'
8arch=('x86_64' 'aarch64')
9url='https://github.com/bnema/nefercap'
10license=('GPL-3.0-only')
11# Loaded at runtime (purego, no cgo): not seen by makepkg's library scan.
12depends=('glibc' 'wayland' 'libxkbcommon' 'vulkan-icd-loader' 'vulkan-driver')
13makedepends=('go>=2:1.27' 'git')
14optdepends=('ffmpeg: screen recording (libx264)'
15	'wl-clipboard: copy screenshots to the clipboard'
16	'neferwl: hidden-workspace capture, HUD exclusion and capture indicator')
17provides=('nefercap')
18conflicts=('nefercap' 'nefercap-bin')
19source=('git+https://github.com/bnema/nefercap.git')
20sha256sums=('SKIP')
21
22pkgver() {
23	cd nefercap
24	# v0.2.0-5-gabc1234 -> 0.2.0.r5.gabc1234. Pre-release tags (v0.3.0-rc1)
25	# are skipped: pacman sorts 0.3.0.rc1 after 0.3.0.
26	git describe --long --tags --abbrev=7 --exclude='*-*' | sed 's/^v//;s/\([^-]*-g\)/r\1/;s/-/./g'
27}
28
29prepare() {
30	cd nefercap
31	export GOPATH="$srcdir/gopath" GOFLAGS='-mod=readonly -modcacherw' GOTOOLCHAIN=local
32	go mod download
33}
34
35build() {
36	cd nefercap
37	export GOPATH="$srcdir/gopath" CGO_ENABLED=0 GOTOOLCHAIN=local GOPROXY=off
38	export GOFLAGS='-mod=readonly -modcacherw -trimpath -buildvcs=false -buildmode=pie'
39	go build -ldflags "-X main.version=$pkgver" -o nefercap ./cmd/nefercap
40}
41
42check() {
43	cd nefercap
44	./nefercap version
45}
46
47package() {
48	cd nefercap
49	install -Dm755 nefercap "$pkgdir/usr/bin/nefercap"
50	install -Dm644 README.md "$pkgdir/usr/share/doc/nefercap/README.md"
51	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
52}