PKGBUILD RawHistoryFolder

1# Built by `make pkg` at the repo root, from `git archive HEAD`.
2pkgname=neferwl
3pkgver=0.0.0
4pkgrel=1
5pkgdesc='Minimal Wayland compositor with column tiling, for the TTY'
6arch=('x86_64')
7url='https://github.com/bnema/neferwl'
8license=('GPL-3.0-only')
9# Loaded at runtime (purego, no cgo): not seen by makepkg's library scan.
10depends=('glibc' 'libinput' 'libxkbcommon' 'seatd' 'systemd-libs' 'vulkan-icd-loader'
11	'vulkan-driver' 'wayland' 'dbus' 'libcap')
12makedepends=('go')
13optdepends=('xwayland-satellite>=0.7: X11 apps'
14	'foot: default terminal'
15	'fuzzel: launcher'
16	'xdg-desktop-portal-gtk: file pickers and settings for apps'
17	'xdg-desktop-portal-wlr: screen sharing and screenshots through the portal'
18	'nefercap: screenshots and screen recording')
19install=neferwl.install
20source=("$pkgname-$pkgver.tar.gz")
21sha256sums=('SKIP')
22
23prepare() {
24	cd "$pkgname-$pkgver"
25	export GOPATH="$srcdir/gopath" GOFLAGS='-mod=readonly -modcacherw' GOWORK=off GOTOOLCHAIN=local
26	go mod download
27	go mod vendor
28}
29
30build() {
31	cd "$pkgname-$pkgver"
32	export CGO_ENABLED=0 GOFLAGS='-mod=vendor -trimpath -buildvcs=false -buildmode=pie' GOPROXY=off GOWORK=off GOTOOLCHAIN=local
33	go build -ldflags "-X main.version=$pkgver" -o neferwl ./cmd/neferwl
34}
35
36check() {
37	cd "$pkgname-$pkgver"
38	./neferwl version
39	./neferwl validate-config examples/config
40}
41
42package() {
43	cd "$pkgname-$pkgver"
44	install -Dm755 neferwl "$pkgdir/usr/bin/neferwl"
45	install -Dm755 packaging/neferwl-session "$pkgdir/usr/bin/neferwl-session"
46	install -Dm644 packaging/neferwl.service "$pkgdir/usr/lib/systemd/user/neferwl.service"
47	install -Dm644 packaging/neferwl-shutdown.target "$pkgdir/usr/lib/systemd/user/neferwl-shutdown.target"
48	install -Dm644 packaging/neferwl.desktop "$pkgdir/usr/share/wayland-sessions/neferwl.desktop"
49	install -Dm644 packaging/neferwl-portals.conf "$pkgdir/usr/share/xdg-desktop-portal/neferwl-portals.conf"
50	install -Dm644 examples/config "$pkgdir/usr/share/doc/neferwl/config.example"
51	install -Dm644 examples/capture-allow "$pkgdir/usr/share/doc/neferwl/capture-allow.example"
52	install -Dm644 README.md "$pkgdir/usr/share/doc/neferwl/README.md"
53	install -Dm644 LICENSE "$pkgdir/usr/share/licenses/neferwl/LICENSE"
54}