1// SPDX-License-Identifier: Apache-2.0
2// SPDX-FileCopyrightText: 2022 The Ebitengine Authors
3
4//go:build darwin || freebsd || linux || netbsd
5
6#include "textflag.h"
7#include "abi_amd64.h"
8#include "go_asm.h"
9#include "funcdata.h"
10
11#define STACK_SIZE 80
12#define PTR_ADDRESS (STACK_SIZE - 8)
13
14// syscall15X calls a function in libc on behalf of the syscall package.
15// syscall15X takes a pointer to a struct like:
16// struct {
17// fn uintptr
18// a1 uintptr
19// a2 uintptr
20// a3 uintptr
21// a4 uintptr
22// a5 uintptr
23// a6 uintptr
24// a7 uintptr
25// a8 uintptr
26// a9 uintptr
27// a10 uintptr
28// a11 uintptr
29// a12 uintptr
30// a13 uintptr
31// a14 uintptr
32// a15 uintptr
33// r1 uintptr
34// r2 uintptr
35// err uintptr
36// }
37// syscall15X must be called on the g0 stack with the
38// C calling convention (use libcCall).
39GLOBL ·syscall15XABI0(SB), NOPTR|RODATA, $8
40DATA ·syscall15XABI0(SB)/8, $syscall15X(SB)
41TEXT syscall15X(SB), NOSPLIT, $STACK_SIZE
42 MOVQ DI, PTR_ADDRESS(SP) // save the pointer
43 MOVQ DI, R11
44
45 MOVQ syscall15Args_f1(R11), X0 // f1
46 MOVQ syscall15Args_f2(R11), X1 // f2
47 MOVQ syscall15Args_f3(R11), X2 // f3
48 MOVQ syscall15Args_f4(R11), X3 // f4
49 MOVQ syscall15Args_f5(R11), X4 // f5
50 MOVQ syscall15Args_f6(R11), X5 // f6
51 MOVQ syscall15Args_f7(R11), X6 // f7
52 MOVQ syscall15Args_f8(R11), X7 // f8
53
54 MOVQ syscall15Args_a1(R11), DI // a1
55 MOVQ syscall15Args_a2(R11), SI // a2
56 MOVQ syscall15Args_a3(R11), DX // a3
57 MOVQ syscall15Args_a4(R11), CX // a4
58 MOVQ syscall15Args_a5(R11), R8 // a5
59 MOVQ syscall15Args_a6(R11), R9 // a6
60
61 // push the remaining parameters onto the stack
62 MOVQ syscall15Args_a7(R11), R12
63 MOVQ R12, 0(SP) // push a7
64 MOVQ syscall15Args_a8(R11), R12
65 MOVQ R12, 8(SP) // push a8
66 MOVQ syscall15Args_a9(R11), R12
67 MOVQ R12, 16(SP) // push a9
68 MOVQ syscall15Args_a10(R11), R12
69 MOVQ R12, 24(SP) // push a10
70 MOVQ syscall15Args_a11(R11), R12
71 MOVQ R12, 32(SP) // push a11
72 MOVQ syscall15Args_a12(R11), R12
73 MOVQ R12, 40(SP) // push a12
74 MOVQ syscall15Args_a13(R11), R12
75 MOVQ R12, 48(SP) // push a13
76 MOVQ syscall15Args_a14(R11), R12
77 MOVQ R12, 56(SP) // push a14
78 MOVQ syscall15Args_a15(R11), R12
79 MOVQ R12, 64(SP) // push a15
80 XORL AX, AX // vararg: say "no float args"
81
82 MOVQ syscall15Args_fn(R11), R10 // fn
83 CALL R10
84
85 MOVQ PTR_ADDRESS(SP), DI // get the pointer back
86 MOVQ AX, syscall15Args_a1(DI) // r1
87 MOVQ DX, syscall15Args_a2(DI) // r2
88 MOVQ X0, syscall15Args_f1(DI) // f1
89 MOVQ X1, syscall15Args_f2(DI) // f2
90
91#ifdef GOOS_darwin
92 CALL purego_error(SB)
93 MOVQ PTR_ADDRESS(SP), DI // reload (DI clobbered by call)
94 MOVQ (AX), AX
95 MOVQ AX, syscall15Args_a3(DI) // save errno
96#endif
97
98 XORL AX, AX // no error (it's ignored anyway)
99 RET
100
101TEXT callbackasm1(SB), NOSPLIT|NOFRAME, $0
102 MOVQ 0(SP), AX // save the return address to calculate the cb index
103 MOVQ 8(SP), R10 // get the return SP so that we can align register args with stack args
104 ADDQ $8, SP // remove return address from stack, we are not returning to callbackasm, but to its caller.
105
106 // make space for first six int and 8 float arguments below the frame
107 ADJSP $14*8, SP
108 MOVSD X0, (1*8)(SP)
109 MOVSD X1, (2*8)(SP)
110 MOVSD X2, (3*8)(SP)
111 MOVSD X3, (4*8)(SP)
112 MOVSD X4, (5*8)(SP)
113 MOVSD X5, (6*8)(SP)
114 MOVSD X6, (7*8)(SP)
115 MOVSD X7, (8*8)(SP)
116 MOVQ DI, (9*8)(SP)
117 MOVQ SI, (10*8)(SP)
118 MOVQ DX, (11*8)(SP)
119 MOVQ CX, (12*8)(SP)
120 MOVQ R8, (13*8)(SP)
121 MOVQ R9, (14*8)(SP)
122 LEAQ 8(SP), R8 // R8 = address of args vector
123
124 PUSHQ R10 // push the stack pointer below registers
125
126 // Switch from the host ABI to the Go ABI.
127 PUSH_REGS_HOST_TO_ABI0()
128
129 // determine index into runtime·cbs table
130 MOVQ $callbackasm(SB), DX
131 SUBQ DX, AX
132 MOVQ $0, DX
133 MOVQ $5, CX // divide by 5 because each call instruction in ·callbacks is 5 bytes long
134 DIVL CX
135 SUBQ $1, AX // subtract 1 because return PC is to the next slot
136
137 // Create a struct callbackArgs on our stack to be passed as
138 // the "frame" to cgocallback and on to callbackWrap.
139 // $24 to make enough room for the arguments to runtime.cgocallback
140 SUBQ $(24+callbackArgs__size), SP
141 MOVQ AX, (24+callbackArgs_index)(SP) // callback index
142 MOVQ R8, (24+callbackArgs_args)(SP) // address of args vector
143 MOVQ DI, (24+callbackArgs_result)(SP) // result
144 LEAQ 24(SP), AX // take the address of callbackArgs
145
146 // Call cgocallback, which will call callbackWrap(frame).
147 MOVQ ·callbackWrap_call(SB), DI // Get the ABIInternal function pointer
148 MOVQ (DI), DI // without <ABIInternal> by using a closure.
149 MOVQ AX, SI // frame (address of callbackArgs)
150 MOVQ $0, CX // context
151
152 CALL crosscall2(SB) // runtime.cgocallback(fn, frame, ctxt uintptr)
153
154 // Get callback result.
155 MOVQ (24+callbackArgs_result)(SP), AX
156 MOVQ (24+callbackArgs_result+8)(SP), DX
157 // Restore XMM0/XMM1 from result[2]/result[3] for struct eightbytes
158 // classified as SSE by the SysV ABI.
159 MOVQ (24+callbackArgs_result+16)(SP), X0
160 MOVQ (24+callbackArgs_result+24)(SP), X1
161 ADDQ $(24+callbackArgs__size), SP // remove callbackArgs struct
162
163 POP_REGS_HOST_TO_ABI0()
164
165 POPQ R10 // get the SP back
166 ADJSP $-14*8, SP // remove arguments
167
168 MOVQ R10, 0(SP)
169
170 RET