1// SPDX-License-Identifier: Apache-2.0
2// SPDX-FileCopyrightText: 2022 The Ebitengine Authors
3
4//go:build !cgo && (darwin || freebsd || linux || netbsd)
5
6/*
7trampoline for emulating required C functions for cgo in go (see cgo.go)
8(we convert cdecl calling convention to go and vice-versa)
9
10C Calling convention cdecl used here (we only need integer args):
111. arg: DI
122. arg: SI
133. arg: DX
144. arg: CX
155. arg: R8
166. arg: R9
17We don't need floats with these functions -> AX=0
18return value will be in AX
19temporary register is R11
20*/
21#include "textflag.h"
22#include "go_asm.h"
23#include "abi_amd64.h"
24
25// these trampolines map the gcc ABI to Go ABI and then calls into the Go equivalent functions.
26
27TEXT x_cgo_init_trampoline(SB), NOSPLIT, $16
28 MOVQ DI, AX
29 MOVQ SI, BX
30 MOVQ ·x_cgo_init_call(SB), R11
31 MOVQ (R11), R11
32 CALL R11
33 RET
34
35TEXT x_cgo_thread_start_trampoline(SB), NOSPLIT, $8
36 MOVQ DI, AX
37 MOVQ ·x_cgo_thread_start_call(SB), R11
38 MOVQ (R11), R11
39 CALL R11
40 RET
41
42TEXT x_cgo_setenv_trampoline(SB), NOSPLIT, $8
43 MOVQ DI, AX
44 MOVQ ·x_cgo_setenv_call(SB), R11
45 MOVQ (R11), R11
46 CALL R11
47 RET
48
49TEXT x_cgo_unsetenv_trampoline(SB), NOSPLIT, $8
50 MOVQ DI, AX
51 MOVQ ·x_cgo_unsetenv_call(SB), R11
52 MOVQ (R11), R11
53 CALL R11
54 RET
55
56TEXT x_cgo_notify_runtime_init_done_trampoline(SB), NOSPLIT, $0
57 JMP ·x_cgo_notify_runtime_init_done(SB)
58
59TEXT x_cgo_bindm_trampoline(SB), NOSPLIT, $0
60 JMP ·x_cgo_bindm(SB)
61
62// func setg_trampoline(setg uintptr, g uintptr)
63TEXT ·setg_trampoline(SB), NOSPLIT, $0-16
64 MOVQ G+8(FP), DI
65 MOVQ setg+0(FP), R11
66 XORL AX, AX
67 CALL R11
68 RET
69
70TEXT threadentry_trampoline(SB), NOSPLIT, $0
71 // See crosscall2.
72 PUSH_REGS_HOST_TO_ABI0()
73
74 // X15 is designated by Go as a fixed zero register.
75 // Calling directly into ABIInternal, ensure it is zero.
76 PXOR X15, X15
77
78 MOVQ DI, AX
79 MOVQ ·threadentry_call(SB), R11
80 MOVQ (R11), R11
81 CALL R11
82
83 POP_REGS_HOST_TO_ABI0()
84 RET
85
86// func callThreadEntryFn(fn uintptr)
87// Calls fn (runtime.mstart) with the frame pointer and other callee-saved
88// registers saved on the stack across the call. mstart returns with BP
89// clobbered (BP==0); saving/restoring BP here (as real cgo's crosscall does)
90// keeps the caller's frame-pointer LEAVE epilogue valid on return.
91TEXT ·callThreadEntryFn(SB), NOSPLIT, $0-8
92 MOVQ fn+0(FP), R11
93 PUSH_REGS_HOST_TO_ABI0()
94
95 // X15 is designated by Go as a fixed zero register.
96 PXOR X15, X15
97
98 CALL R11
99
100 POP_REGS_HOST_TO_ABI0()
101 RET
102
103TEXT ·call5(SB), NOSPLIT, $0-56
104 MOVQ fn+0(FP), R11
105 MOVQ a1+8(FP), DI
106 MOVQ a2+16(FP), SI
107 MOVQ a3+24(FP), DX
108 MOVQ a4+32(FP), CX
109 MOVQ a5+40(FP), R8
110
111 XORL AX, AX // no floats
112
113 PUSHQ BP // save BP
114 MOVQ SP, BP // save SP inside BP bc BP is callee-saved
115 SUBQ $16, SP // allocate space for alignment
116 ANDQ $-16, SP // align on 16 bytes for SSE
117
118 CALL R11
119
120 MOVQ BP, SP // get SP back
121 POPQ BP // restore BP
122
123 MOVQ AX, ret+48(FP)
124 RET