1// SPDX-License-Identifier: Apache-2.0
2// SPDX-FileCopyrightText: 2022 The Ebitengine Authors
3
4//go:build darwin || linux
5
6/*
7trampoline for emulating required C functions for cgo in go (see cgo.go)
8(we convert cdecl calling convention to go and vice-versa)
9
10Since we're called from go and call into C we can cheat a bit with the calling conventions:
11 - in go all the registers are caller saved
12 - in C we have a couple of callee saved registers
13
14=> we can use BX, R12, R13, R14, R15 instead of the stack
15
16C Calling convention cdecl used here (we only need integer args):
171. arg: DI
182. arg: SI
193. arg: DX
204. arg: CX
215. arg: R8
226. arg: R9
23We don't need floats with these functions -> AX=0
24return value will be in AX
25*/
26#include "textflag.h"
27#include "go_asm.h"
28
29// these trampolines map the gcc ABI to Go ABI and then calls into the Go equivalent functions.
30
31TEXT x_cgo_init_trampoline(SB), NOSPLIT, $16
32 MOVQ DI, AX
33 MOVQ SI, BX
34 MOVQ ·x_cgo_init_call(SB), DX
35 MOVQ (DX), CX
36 CALL CX
37 RET
38
39TEXT x_cgo_thread_start_trampoline(SB), NOSPLIT, $8
40 MOVQ DI, AX
41 MOVQ ·x_cgo_thread_start_call(SB), DX
42 MOVQ (DX), CX
43 CALL CX
44 RET
45
46TEXT x_cgo_setenv_trampoline(SB), NOSPLIT, $8
47 MOVQ DI, AX
48 MOVQ ·x_cgo_setenv_call(SB), DX
49 MOVQ (DX), CX
50 CALL CX
51 RET
52
53TEXT x_cgo_unsetenv_trampoline(SB), NOSPLIT, $8
54 MOVQ DI, AX
55 MOVQ ·x_cgo_unsetenv_call(SB), DX
56 MOVQ (DX), CX
57 CALL CX
58 RET
59
60TEXT x_cgo_notify_runtime_init_done_trampoline(SB), NOSPLIT, $0
61 CALL ·x_cgo_notify_runtime_init_done(SB)
62 RET
63
64// func setg_trampoline(setg uintptr, g uintptr)
65TEXT ·setg_trampoline(SB), NOSPLIT, $0-16
66 MOVQ G+8(FP), DI
67 MOVQ setg+0(FP), BX
68 XORL AX, AX
69 CALL BX
70 RET
71
72TEXT threadentry_trampoline(SB), NOSPLIT, $16
73 MOVQ DI, AX
74 MOVQ ·threadentry_call(SB), DX
75 MOVQ (DX), CX
76 CALL CX
77 RET
78
79TEXT ·call5(SB), NOSPLIT, $0-56
80 MOVQ fn+0(FP), BX
81 MOVQ a1+8(FP), DI
82 MOVQ a2+16(FP), SI
83 MOVQ a3+24(FP), DX
84 MOVQ a4+32(FP), CX
85 MOVQ a5+40(FP), R8
86
87 XORL AX, AX // no floats
88
89 PUSHQ BP // save BP
90 MOVQ SP, BP // save SP inside BP bc BP is callee-saved
91 SUBQ $16, SP // allocate space for alignment
92 ANDQ $-16, SP // align on 16 bytes for SSE
93
94 CALL BX
95
96 MOVQ BP, SP // get SP back
97 POPQ BP // restore BP
98
99 MOVQ AX, ret+48(FP)
100 RET